Componentes del crecimiento

Tradicionalmente, cuando realizamos un análisis del crecimiento, comparamos los datos actuales con los del año anterior o cualquier otro periodo en valores absolutos o porcentuales. La mayor parte de empresas no van a buscar mayor detalle y se conforman con esta métrica aplicada a las dimensiones de producto, división, geográfica, etc.

El análisis de componentes del crecimiento añade un poco más de sofisticación descomponiendo el crecimiento en varios factores para conocer como el volumen de ventas (unidades vendidas) ha afectado al crecimiento o el efecto que ha tenido la variación del precio o el impacto de los nuevos lanzamientos o el de los productos descartado, también se incluye un efecto genérico, habitualmente un remanente debido a que en ocasiones pueden aumentar o disminuir la proporción de venta de productos caros puesto que incluso manteniendo el volumen invariable y el mismo precio podríamos tener este efecto.

Aunque la composición del crecimiento puede realizarse con diferentes variables, en este artículo lo hemos hecho con 5: Efecto precio, Efecto volumen, Impacto genérico, Productos nuevos y Productos discontinuados.

El resultado es un gráfico como el de arriba. La lectura de este caso es que la empresa ha perdido algo más de 11 millones de un periodo a otro a pesar de que ha vendido más volumen (que le han reportado casi 4,5 millones), además ha impulsado algo las ventas con productos nuevos pero la caida de ventas no se ha podido evitar debido a la rebaja de precios. En este caso el efecto genérico y el de productos discontinuados no ha tenido un gran impacto.

En las fórmulas hemos utilizado los sufijos Ant para referirnos al periodo previo y Act para el periodo actual. Las fórmulas genéricas serian:

– Efecto precio = Unidades Ant * (Precio Act – Precio Ant)
– Efecto volumen = Precio Ant * (Unidades Act – Unidades Ant)
– Efecto genérico = (Unidades Act – Unidades Ant) * (Precio Act– Precio Ant)
– Efecto nuevos productos = Ventas actuales de elementos que no estaban en el periodo previo.
– Efecto productos discontinuados = Ventas de elementos que estaban en el periodo previo y que en el periodo actual no están.

Es importe remarcar que para el cálculo de las tres primeras debemos descartar aquellas ventas de productos que o bien no tienen venta anterior o bien no disponen de venta actual, puesto que estas ventas son utilizadas en el cálculo de los dos componentes posteriores.
Para poder seguir el ejemplo hemos dispuesto dos tablas, en una se incluyen las ventas y en la otra una jerarquia de productos. Además construiremos una tabla de fechas como apoyo a la tabla de ventas y una tabla manual. La tabla de ventas dispone de datos de los años 2013 y 2014 por lo que en el ejemplo solo podremos ver el crecimiento de 2014 respecto de 2013.

Disponéis de un archivo de Excel con los datos de origen así como un archivo de Power BI (en un zip) para abrirlo con el Desktop. Al abrir el pbix deberéis cambiar el origen de datos por la carpeta donde tengáis el archivo Excel.

Con la opción de introducir datos creamos una nueva tabla introduciendo a mano los datos como la siguiente imagen.

Creamos una tabla para las fechas

Fechas = CALENDAR (MINX (Ventas; [Fecha]); MAXX (Ventas; [Fecha]))

Añadimos la columna “Año”

Año = YEAR(Fechas[Fecha])

Relacionamos las tablas

Creamos las medidas necesarias:

Valores Act = SUM(Ventas[Importe])

Valores Ant = CALCULATE(Ventas[Valores Act];SAMEPERIODLASTYEAR(Fechas[Fecha]))

Crecimiento = Ventas[Valores Act] – Ventas[Valores Ant]

Unidades Act = SUM(Ventas[Unidades])

Unidades Ant = CALCULATE(Ventas[Unidades Act]; SAMEPERIODLASTYEAR(Fechas [Fecha]))

Precio Act = DIVIDE(Ventas[Valores Act]; Ventas[Unidades Ant])

Precio Ant = CALCULATE(Ventas[Precio Act]; SAMEPERIODLASTYEAR(Fechas[Fecha]))

Finalmente componemos el cálculo final:

Componentes de crecimiento = 

VAR ImpactDelPrecio =
SUMX(
ADDCOLUMNS(
VALUES(Productos[Producto]);
"Precio"; [Unidades Ant]
* (
IF(
ISBLANK([Precio Act]) || ISBLANK([Precio Ant]) || [Precio Act]=0 || [Precio Ant]=0;
0;
[Precio Act] - [Precio Ant]
)
)
);
[Precio]
)


VAR ImpactoDelVolumen =
SUMX(
ADDCOLUMNS(
VALUES(Productos[Producto]);
"Volumen"; (
IF(
ISBLANK([Precio Act]) || ISBLANK([Precio Ant]) || [Precio Act]=0 || [Precio Ant]=0;
0;
[Unidades Act] - [Unidades Ant]
)
)
* [Precio Ant]
);
[Volumen]
)


VAR ImpactoGenerico =
SUMX(
ADDCOLUMNS(
VALUES(Productos[Producto]);
"Generico"; IF(
ISBLANK([Precio Act]) || ISBLANK([Precio Ant]) || [Precio Act]=0 || [Precio Ant]=0;
0;
([Precio Act] - [Precio Ant])
)
* ([Unidades Act] - [Unidades Ant])
);
[Generico]
)


VAR ImpactoNuevosProductos =
SUMX(
ADDCOLUMNS(
VALUES(Productos[Producto]);
"Nuevos"; IF(ISBLANK([Valores Ant]) || [Valores Ant] = 0; [Valores Act]; 0)
);
[Nuevos]
)


VAR ImpactoDiscontProductosPrev =
SUMX(
ADDCOLUMNS(
VALUES(Productos[Producto]);
"Discont"; IF(ISBLANK([Valores Act]) || [Valores Act] = 0; [Valores Ant]; 0)
);
[Discont]
)
VAR ImpactoDiscontProductos = - ImpactoDiscontProductosPrev


RETURN
SWITCH(
MAX('Efectos Crecimiento'[Orden]);
1; ImpactDelPrecio;
2; ImpactoDelVolumen;
3; ImpactoGenerico;
4; ImpactoNuevosProductos;
5; ImpactoDiscontProductos;
BLANK()
)

Mediante un gráfico del tipo “Waterfall” podemos graficar el resultado

También podemos añadir una matriz con el detalle de los productos, familias o el nivel detetalle deseado

Para la confección de este post he traducido y adaptado el original publicado en Business Intelligist.

 

Un comentario sobre “Componentes del crecimiento

  1. Pingback: Explicar el crecimiento – Power BI y Business Intelligence

Deja un comentario

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *